Syntactic Analysis
 
TypeConFile ::= Production*.
Production ::= Identifier Delim Alternatives `.'.
Delim ::= `:' / `::='.
Alternatives ::=
Alternatives `/' Alternative /
Alternatives `//' Separator /
Alternative .
Alternative ::= Element*.
Separator ::= Symbol.
Element ::=
Symbol /
Connection /
Modification /
`(' Alternatives `)' /
`[' Alternatives `]' /
Element `*' /
Element `+' .
Connection ::= `&' Symbol.
Modification ::= `@' Symbol / `$' Symbol.
Symbol ::= Identifier / Literal.
TypeMapFile ::=
(`MAPSYM' SymbolMapping+ / `MAPRULE' RuleMapping+ / `MAPCHAINS')+ .
SymbolMapping: Identifier `::=' Members `.' .
Members: Identifier+ .
RuleMapping: Rule Rewrite RuleName `.' .
Rule: Identifier Delimiter RHS .
Delimiter: `:' / `::=' .
RHS: Element* .
Element: Identifier / Text .
Rewrite: `<' RewriteRHS `>' .
RewriteRHS: (Position / Text)+ .
Position: `$' Integer .
RuleName: / `:' Identifier .
TypePerrFile ::= ErrorSpecs.
ErrorSpecs ::= ErrorSpecs SeparatorSpecs /
ErrorSpecs BracketSpecs /
ErrorSpecs SkipSpecs / .
SeparatorSpecs ::= `$SEPA' Symbols .
BracketSpecs ::= `$BRACKET' Symbols .
SkipSpecs ::= `$SKIP' Symbols .
Symbols ::= Symbols Symbol .
Symbol ::= Identifier / Literal .
|
